org.eclipse.amp.amf/plugins/org.eclipse.amp.amf.testing/src/org/eclipse/amp/amf/testing/ATest.xtext

grammar org.eclipse.amp.amf.testing.ATest with org.eclipse.xtext.common.Terminals

generate aTest "http://www.eclipse.org/amp/amf/testing/ATest"
import "http://www.eclipse.org/emf/2002/Ecore" as ecore
import 'platform:/resource/org.eclipse.amp.amf.acore/src/model/metaabm.ecore'

Model :
	(name=STRING)?
	(description=PLAIN_STRING)?
	(tests=Tests)?
	(contraints+=Constraint)*;

Tests :
	'TESTS' importURI=STRING;

Constraint :
	measure=Measure "(" agent=[SAgent|STRING]":"attribute=[SAttribute|STRING] (":" qualifier=[SStateValue|STRING])? ")" ("=" "[" minValue=(IntValue|RealValue) "," maxValue=(IntValue|RealValue) "]");

enum Measure :
	COUNT = "Count" | AVERAGE = "Average" | SUM = "Sum" | MINIMUM = "Minimum" | MAXIMUM = "Maximum";

IntValue :
	value=INT;

RealValue :
	value=REAL;

terminal REAL :
	"-"? INT ("." INT)?;
	
terminal PLAIN_STRING	: 
  '«'( '\\' ('b'|'t'|'n'|'f'|'r'|'"'|"'"|'\\') | !('\\'|'«'|'»') )*'»';