Skip to main content
aboutsummaryrefslogtreecommitdiffstats
blob: 3dca23f2cf9e878a4d3d2e215195a83f08fcf9fd (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
/*******************************************************************************
 * Copyright (c) 2007,2008 Tata Consultancy Services and others.
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v1.0
 * which accompanies this distribution, and is available at
 * http://www.eclipse.org/legal/epl-v10.html
 *
 * Contributors:
 *     TCS - initial implementation for ModelMorf
 *     E.D.Willink - alignment with evolved specification
 *******************************************************************************/

-- Transforming an arbitrary boolean expression into disjunctive normal form by using 
-- DeMorgan's law
import exprMM : 'DNFMM.emof'::deMorgansLawMM; 

transformation DNF_bbox(expr1:exprMM, expr2:exprMM)
{

	-- a.(b+c) = (a.b) + (a.c)
	top relation EqualByDistributionLaw1
	{
		p:exprMM::Expr;
		emptySequence:Sequence(exprMM::Expr);

		/*replace*/ domain expr1 
		e1:And 
		{
			expr = e1s:Sequence(Expr)
			{
				a:Expr{parent = e1},
				e2:Or 
				{
					expr = e2s:Sequence(Expr)
					{
						b:Expr{parent = e2},
						c:Expr{parent = e2}
						++ emptySequence   -- To ensures that OR only has two operands.
					},
					parent = e1
				}
				++ emptySequence   -- To ensure that AND only has two operands.
			},
			parent = p
		}
		{emptySequence = Sequence{}};

		enforce domain expr2 
		e3:Or 
		{
			expr = e3s:Sequence(Expr)
			{
				e4:And 
				{
					expr = e4s:Sequence(Expr)
					{
						a:Expr{parent = e4},
						b:Expr{parent = e4}
						++ emptySequence
					},
					parent = e3
				},
				e5:And 
				{
					expr = e5s:Sequence(Expr)
					{
						a_c:Expr{parent = e5},
						c:Expr{parent = e5}
						++ emptySequence
					},
					parent = e3
				}
				++ emptySequence
			},
			parent = p
		};

		where 
		{
			CopyOfExpr(a, a_c);
		}
	}

	-- (b+c).a = (b.a) + (c.a)
	top relation EqualByDistributionLaw2
	{
		p:exprMM::Expr;
		emptySequence:Sequence(exprMM::Expr);

		/*replace*/ domain expr1 
		e1:And 
		{
			expr = e1s:Sequence(Expr)
			{
				e2:Or 
				{
					expr = e2s:Sequence(Expr)
					{
						b:Expr{parent = e2},
						c:Expr{parent = e2}
						++ emptySequence   -- To ensures that OR only has two operands.
					},
					parent = e2
				},
				a:Expr{parent = e1}
				++ emptySequence   -- To ensure that AND only has two operands.
			},
			parent = p
		}
		{emptySequence = Sequence{}};

		enforce domain expr2 
		e3:Or 
		{
			expr = e3s:Sequence(Expr)
			{
				e4:And 
				{
					expr = e4s:Sequence(Expr)
					{
						b:Expr{parent = e4},
						a:Expr{parent = e4}
						++ emptySequence
					},
					parent = e3
				},
				e5:And 
				{
					expr = e5s:Sequence(Expr)
					{
						c:Expr{parent = e5},
						a_c:Expr{parent = e5}
						++ emptySequence
					},
					parent = e3
				}
				++ emptySequence
			},
			parent = p
		};

		when 
		{
			not EqualByDistributionLaw1(e1, _);   -- lest (a+b).(c+d) transformed twice!
		}

		where 
		{
			CopyOfExpr(a, a_c);
		}
	}

	-- ~(a+b) = ~a.~b
	top relation EqualByDeMorganLaw1
	{
		p:exprMM::Expr;
		emptySequence:Sequence(exprMM::Expr);

		/*replace*/ domain expr1 
		e1:Not 
		{
			expr = e1s:Sequence(Expr)
			{
				e2:Or 
				{
					expr = e2s:Sequence(Expr)
					{
						a:Expr{parent = e2},
						b:Expr{parent = e2}
						++ emptySequence   -- To ensures that OR only has two operands.
					},
					parent = e1
				}
				++ emptySequence   -- To ensure that AND only has two operands.
			},
			parent = p
		}
		{emptySequence = Sequence{}};

		enforce domain expr2 
		e3:And 
		{
			expr = e3s:Sequence(Expr)
			{
				e4:Not 
				{
					expr = e4s:Sequence(Expr)
					{
						a:Expr{parent = e4}
						++ emptySequence
					},
					parent = e3
				},
				e5:Not 
				{
					expr = e5s:Sequence(Expr)
					{
						b:Expr{parent = e5}
						++ emptySequence
					},
					parent = e3
				}
				++ emptySequence
			},
			parent = p
		};
	}

	-- ~(a.b) = ~a+~b
	top relation EqualByDeMorganLaw2
	{
		p:exprMM::Expr;
		emptySequence:Sequence(exprMM::Expr);

		/*replace*/ domain expr1 
		e1:Not 
		{
			expr = e1s:Sequence(Expr)
			{
				e2:And 
				{
					expr = e2s:Sequence(Expr)
					{
						a:Expr{parent = e2},
						b:Expr{parent = e2}
						++ emptySequence   -- To ensure that AND only has two operands.
					},
					parent = e1
				}
				++ emptySequence   -- To ensure that NOT only has one operand.
			},
			parent = p
		}
		{emptySequence = Sequence{}};

		enforce domain expr2 
		e3:Or 
		{
			expr = e3s:Sequence(Expr)
			{
				e4:Not 
				{
					expr = e4s:Sequence(Expr)
					{
						a:Expr{parent = e4}
						++ emptySequence
					},
					parent = e3
				},
				e5:Not 
				{
					expr = e5s:Sequence(Expr)
					{
						b:Expr{parent = e5}
						++ emptySequence
					},
					parent = e3
				}
				++ emptySequence
			},
			parent = p
		};
	}

	relation CopyOfExpr
	{
		domain expr1 e1:Expr {};

		enforce domain expr2 e2:Expr {} implementedby CopyExpr(e1, e2);
	}
}

Back to the top