summaryrefslogtreecommitdiffstats
blob: 5d689afed44f4d6fa6fcb8c9ce0acd0e35d201e5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
-- @authors		Frédéric Jouault
-- @date		2007/05/21
-- @description	This TCS model defines the syntax of the LOTOS language.
-- @see			ftp://ftp.inrialpes.fr/pub/vasy/publications/others/Turner-96.pdf
syntax LOTOS(k = 0) {

	primitiveTemplate identifier for String default using NAME:
		value = "%token%";

	primitiveTemplate identifierOrKeyword for String using NAME orKeyword:
		value = "%token%";

	primitiveTemplate stringSymbol for String using STRING:
		value = "%token%",
		serializer="'\'' + %value%.toCString() + '\''";

	primitiveTemplate integerSymbol for Integer default using INT:
		value = "Integer.valueOf(%token%)";

	primitiveTemplate floatSymbol for Double default using FLOAT:
		value = "Double.valueOf(%token%)";

	template Specification main context
		:	"specification" name
			(isDefined(gates) ? "[" gates{separator = ","} "]")
			":" (isExit ? "exit" : "noexit")
			[ types ] {nbNL = 2}
			"behaviour" [
				(isDefined(definition) ? definition)
			] "endspec"
		;

	template Definition
		:	[
				behaviour
			] (isDefined(declarations) ? "where" [
				declarations
			] {nbNL = 2})
		;

	template TypeOrProcessDeclaration abstract;
	
	template Process context
		:	"process" name
			(isDefined(gates) ? "[" gates{separator = ","} "]")
			(isDefined(variables) ? "(" variables{separator = ","} ")")
			":" (isExit ? "exit" : "noexit") ":=" definition "endproc"
		;

-- @begin Behaviour
	template Behaviour abstract operatored(Behaviour);
	
	template Let context nonPrimary
		:	"let" variables "=" value "in"
			[ behaviour ]
		;

	template Choice context nonPrimary
		:	"choice" variables "[]"
			[ behaviour ]
		;
		
	template Hide nonPrimary
		:	"hide" gates{separator = ","} "in"
			[ behaviour ]
		;

	template ProcessCall
		:	name "[" gates{separator = ","} "]"
			(isDefined(arguments) ? "(" arguments{separator = ","} ")")
		;	
		
	operatorTemplate SimpleParallel(operators = parOp, source = 'left', storeRightTo = 'right');
	operatorTemplate GatedParallel(operators = gatedParOp, source = 'left', storeRightTo = 'right')
		:	gates{separator = ","} "]|"
		;

	operatorTemplate GuardedBehaviour(operators = guardedOp, source = behaviour)
		:	"[" guard "]"	-- prefix to operator
		;

	operatorTemplate ActionBehaviour(operators = semiOp, source = behaviour) context
		:	action		-- prefix to operator
		;
		
	operatorTemplate Alternative(operators = alternativeOp, source = 'left', storeRightTo = 'right');
-- @end Behaviour

-- @begin Actions
	template Action abstract;
	
	template GateAction context
		:	gate
-- TODO: resolve ambiguity when guard is outside
			(isDefined(communications) ? communications{forcedLower = 1}
				(isDefined(guard) ? "[" guard "]")
			)
		;
		
	template Communication abstract;
	
	template InComm
		:	"?" declarations
		;
		
	template OutComm
		:	"!" value
		;
-- @end Actions

-- @begin Guards
	template GuardExpression abstract;
	
	template EqualityTestGuardExp(disambiguate = "value EQ")
		:	left "=" right
		;
		
	template BooleanGuardExp
		:	value
		;
-- @end Guards

-- @begin Values
	template Value abstract operatored(Value);
	
	template Variable
		:	declaration{refersTo = name}
		;
		
	template OperationCall
		:	operationName "(" arguments{separator = ","} ")"
		;
		
	template IntegerVal
		:	value
		;

	template BooleanVal
		:	(value ? "true" : "false")
		;
		
	operatorTemplate CastVal(operators = opOf, source = 'value')
		:	toType
		;

	operatorTemplate OperatorCall(operators =
			opPlus
			opEq opGe opGt opLe opLt opNe
			opAnd opOr
			, source = 'left', storeOpTo = operatorName, storeRightTo = 'right');
-- @end Values
	
	template VariableDeclaration addToContext
		:	name
		;

	template VariableDeclarations
		:	declarations{separator = ","} ":" type
		;
		
-- @begin Types
	template Type abstract;
	
	template LibraryList
		:	"library" names{separator = ","} "endlib"
		;
		
	template TypeDefinition
		:	"type" name "is" types{separator = ","}	[
				"sorts" sorts{separator = ","}
				"opns" [
					operations
				]
				"eqns" [
					equations
				] {endNL = false}
			] "endtype"
		;
		
	template Operations
		:	declarations{separator = ","}
			":" parameterTypes{separator = ","} "->" returnType
		;
		
	template OperationDeclaration addToContext
		:	name
		;
		
	template Equations context
		:	"forall" declarations{separator = ","} [
				ofSorts
			] {indentIncr = 0, nbNL = 2, endNL = false}
		;
		
	template OfSort
		:	"ofsort" name [
				equations
			] {endNL = false}
		;
		
	template Equation abstract;
	
	template SimpleEquation
		:	left "=" right ";"
		;
		
	template GuardedEquation(disambiguate = "guardExpression IMPLIES")
		:	guard "=>" equation
		;
-- @end Types

	symbols {
		lsquarersquare		= "[]";
		lsquare		= "[";
		rsquare		= "]"	: rightSpace;
		excl		= "!";
		coma		= ","	: leftNone, rightSpace;
		lparen		= "(";
		rparen		= ")"	: leftNone, rightSpace;
		lcurly		= "{"	: leftSpace;
		rcurly		= "}"	: leftNone, rightSpace;
		semi		= ";"	: leftNone, rightSpace;
		colon		= ":"	: leftSpace, rightSpace;	-- except after def where it is leftNone, rightSpace
		pipe		= "|"	: leftSpace, rightSpace;
		sharp		= "#"	: leftSpace;
		qmark		= "?";
		coloncolon	= "::"	: leftNone, rightNone;
		pipe3		= "|||";
		pipelsquare	= "|[";
		rsquarepipe	= "]|";
		coloneq		= ":=";
		implies		= "=>"	: leftSpace, rightSpace;

		-- operator symbols
		point		= "."	: leftNone;
		rarrow		= "->"	: leftSpace, rightSpace;
		minus		= "-"	: leftSpace, rightSpace;
		star		= "*"	: leftSpace, rightSpace;
		slash		= "/"	: leftSpace, rightSpace;
		plus		= "+"	: leftSpace, rightSpace;
		eq		= "="	: leftSpace, rightSpace;
		gt		= ">"	: leftSpace, rightSpace;
		lt		= "<"	: leftSpace, rightSpace;
		ge		= ">="	: leftSpace, rightSpace;
		le		= "<="	: leftSpace, rightSpace;
		ne		= "<>"	: leftSpace, rightSpace;
		larrow		= "<-"	: leftSpace, rightSpace;
	}
	
	operators Behaviour {
		priority 0, right {
			semiOp		= ";", 1;	-- prefix
		}
		
		priority 1 {
			guardedOp		= "->", 1;	-- prefix
		}
		
		priority 2 {
			alternativeOp	= "[]", 2;
		}
		
		priority 3 {
			parOp			= "|||", 2;
			gatedParOp		= "|[", 2;
		}

--		priority 4 {
--			disableOp		= "|>", 2;
--		}

--		priority 5 {
--			enableOp		= ">>", 2;
--		}
	}

	operators Value {
		priority 0 {
			opOf	= "of", 2;
		}
		
		priority 1 {
			opPlus	= plus, 2;
		}
		
		priority 2 {
			opEq	= "eq", 2;
			opGe	= ge, 2;
			opGt	= gt, 2;
			opLe	= le, 2;
			opLt	= lt, 2;
			opNe	= "neq", 2;
		}
		
		priority 3 {
			opAnd = "and", 2;
			opOr = "or", 2;
		}
	}
	
	token COMMENT : multiLine(start = "(*", end = "*)");

	lexer = "
%options testLiterals = false;

NL
	:	(	'\\r' '\\n'
		|	'\\n' '\\r'	//Improbable
		|	'\\r'
		|	'\\n'
		)
	{newline();}
	;

WS
	:	(	' '
		|	'\\t'
		)
	;

%protected
DIGIT
	:	'0'..'9'
	;

%protected
ALPHA
	:	'a'..'z'
	|	'A'..'Z'
	|	'_'
	//For Unicode compatibility (from 0000 to 00ff)
	|	'\\u00C0' .. '\\u00D6'
	|	'\\u00D8' .. '\\u00F6'
	|	'\\u00F8' .. '\\u00FF'
	;

%protected
SNAME
%v2	options {
%v2		testLiterals = true;
%v2	}
	:	(ALPHA) (ALPHA | DIGIT)*
;

NAME
	:	(
%v3			SNAME
%v2			s:SNAME {if(s.getType() != SNAME) $setType(s.getType());}
		|	'\"'!
			(	ESC
			|	'\\n' {newline();}
			|	~('\\\\'|'\\\"'|'\\n')
			)*
			'\"'!
%v3			{setText(ei.unescapeString(getText(), 1));}
		)
	;

INT
	:	(DIGIT)+
%v2		(('.' DIGIT)=> '.' (DIGIT)+ {$setType(FLOAT);})?
	;

%v3	FLOAT	:	DIGIT+ '.' DIGIT*	;

%protected
ESC
	:	'\\\\'!
		(	'n' %v2{%setText(\"\\n\");}
		|	'r' %v2{%setText(\"\\r\");}
		|	't' %v2{%setText(\"\\t\");}
		|	'b' %v2{%setText(\"\\b\");}
		|	'f' %v2{%setText(\"\\f\");}
		|	'\"' %v2{%setText(\"\\\"\");}
		|	'\\'' %v2{%setText(\"\\'\");}
		|	'\\\\' %v2{%setText(\"\\\\\");}
		|	(
				('0'..'3')
				(
%v2					options {
%v2						warnWhenFollowAmbig = false;
%v2					}
				:	('0'..'7')
					(
%v2						options {
%v2							warnWhenFollowAmbig = false;
%v2						}
					:	'0'..'7'
					)?
				)?
			|	('4'..'7')
				(
%v2					options {
%v2						warnWhenFollowAmbig = false;
%v2					}
				:	('0'..'7')
				)?
			)
				{
%v2					String s = %getText;
%v2					int i;
%v2					int ret = 0;
%v2					String ans;
%v2					for (i=0; i<s.length(); ++i)
%v2						ret = ret*8 + s.charAt(i) - '0';
%v2					ans = String.valueOf((char) ret);
%v2					%setText(ans);
				}
		)
	;

STRING
	:	'\\''!
		(	ESC
		|	'\\n' {newline();}
		|	~('\\\\'|'\\''|'\\n')
		)*
		'\\''!
%v3			{setText(ei.unescapeString(getText(), 1));}
	;

	";

}