summaryrefslogtreecommitdiffstats
blob: c34382b2d0efc3388f4d72dda78c170136109134 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
-- @name		FScript
-- @version		1.0
-- @authors		Frédéric Jouault
-- @date		20080205
-- @description	Concrete syntax of the FScript Fractal action language.

-- The different sections of a TCS model have been enclosed between BEGIN and END
-- comments below. Additional information is provided below each BEGIN comment.
-- The main sections of interest are "Class templates", and
-- "Operator table" (the latter only for DSLs using operators).
syntax FScript {

-- BEGIN Primitive templates
-- Specifies representation of primitive types.
-- Only needs modification when default lexer is not satisfactory.
-- Generally modified along with the lexer.
	primitiveTemplate identifier for String default using NAME:
		value = "%token%";

	primitiveTemplate stringSymbol for String using STRING:
		value = "%token%",
		serializer="'\'' + %value%.toCString() + '\''";

	primitiveTemplate floatSymbol for Double default using FLOAT:
		value = "Double.valueOf(%token%)";
-- END Primitive templates

-- BEGIN Class templates
-- Specifies representation of classes.
-- This is the main section to work on.
	template Procedure main abstract;
	
	template Action context
		:	"action" name "(" parameters{separator = ","} ")" body
		;
		
	template VariableDefinition addToContext
		:	name
		;

	template Block context
		:	"{" [
				statements
			] "}"
		;
		
-- @begin Control Structures
	template ControlStructure abstract;
	
	template VariableAssignment
		:	variable{refersTo = name, autoCreate = ifmissing, createIn = '#context'.freeVariables} "=" value ";"
		;
		
	template Conditional
		:	"if" "(" condition ")" then
			(isDefined(else) ? "else" else)
		;
		
	template Iteration
		:	"for" variable ":" source body
		;
		
	template ReturnStat
		:	"return" (isDefined(expression) ? expression) ";"
		;

	template PrimitiveAction abstract;
	
	template BindAction
		:	"bind" "(" clientInterface "," serverInterface ")" ";"
		;
-- @end Control Structures

-- @begin FPath (copied from FPath.tcs in the FPath Language Project)
	template Expression abstract operatored;
	
	template ContextExp
		:	"."
		;
		
	template VariableExp
		:	"$" definition{refersTo = name}
		;

	template FunctionCallExp
		:	name "(" arguments{separator = ","} ")"
		;

	template NumberExp
		:	'value'
		;

	template StringExp
		:	'value'{as = stringSymbol}
		;

	operatorTemplate PathExp(operators = opSlash, source = initialNodeSet)
		:	steps{separator = "/"}
		;

	operatorTemplate BinaryOperatorExp(operators =
			opMul opDiv
			opPlus opMinus2
			opLt opGt opLe opGe opEq opNe
			opAnd opOr
			, source = 'left', storeOpTo = operator, storeRightTo = 'right'
		);

	operatorTemplate UnaryOperatorExp(operators =
			opNot opMinus1
			, source = operand, storeOpTo = operator
		);
		
	template Step
		:	axis "::" test (isDefined(predicates) ? "[" predicates{separator = "]" "["} "]")
		;

	template Test abstract;
	
	template WildcardTest
		:	"*"
		;

	template NameTest
		:	name
		;

	enumerationTemplate Axis
		:	#component				= "component",
			#'internal-interface'	= "internal-interface",
			#interface				= "interface",
			#attribute				= "attribute",
			#binding				= "binding",
			#child					= "child",
			#parent					= "parent",
			#descendant				= "descendant",
			#ancestor				= "ancestor",
			#sibling				= "sibling",
			#'descendant-or-self'	= "descendant-or-self",
			#'ancestor-or-self' 	= "ancestor-or-self",
			#'sibling-or-self'		= "sibling-or-self"
		;
-- @end FPath
-- END Class templates

-- BEGIN Special symbols
-- Possible modifications:
--	- Addition of new symbols.
--	- Modification of spaces information.
--	- Removal of unused symbols so that using these symbols results in lexical
--	error rather than parsing error.
	symbols {
		lsquare		= "[";
		rsquare		= "]"	: rightSpace;
		excl		= "!";
		coma		= ","	: leftNone, rightSpace;
		lparen		= "(";
		rparen		= ")"	: leftNone, rightSpace;
		lcurly		= "{"	: leftSpace;
		rcurly		= "}"	: leftNone, rightSpace;
		semi		= ";"	: leftNone, rightSpace;
		colon		= ":"	: leftSpace, rightSpace;
		pipe		= "|"	: leftSpace, rightSpace;
		sharp		= "#"	: leftSpace;
		qmark		= "?";
		coloncolon	= "::"	: leftNone, rightNone;

		-- operator symbols
		point		= "."	: leftNone;
		rarrow		= "->"	: leftNone;
		minus		= "-"	: leftSpace, rightSpace;
		star		= "*"	: leftSpace, rightSpace;
		slash		= "/"	: leftSpace, rightSpace;
		plus		= "+"	: leftSpace, rightSpace;
		eq			= "="	: leftSpace, rightSpace;
		eqeq		= "=="	: leftSpace, rightSpace;
		gt			= ">"	: leftSpace, rightSpace;
		lt			= "<"	: leftSpace, rightSpace;
		ge			= ">="	: leftSpace, rightSpace;
		le			= "<="	: leftSpace, rightSpace;
		ne			= "<>"	: leftSpace, rightSpace;
		larrow		= "<-"	: leftSpace, rightSpace;
	}
-- END Special symbols

-- BEGIN Operator table
-- Defines all operators with their priority, arity, and associativity.
-- All defined operators must be used in operator templates.
	operators {
		priority 0 {	-- highest priority
			opSlash = slash, 2;
		}
		
		priority 1 {
			opNot = "not", 1;
			opMinus1 = minus, 1;
		}
		
		priority 2 {
			opMul = star, 2;
			opDiv = "div", 2;
		}

		priority 3 {
			opPlus = plus, 2;
			opMinus2 = minus, 2;
		}

		priority 4 {
			opLt = lt, 2;
			opGt = gt, 2;
			opLe = le, 2;
			opGe = ge, 2;
			opEq = eqeq, 2;
			opNe = ne, 2;
		}

		priority 5 {
			opAnd = "and", 2;
			opOr = "or", 2;
		}
	}
-- END Operator table


-- BEGIN Lexer
-- Specifies the lexical entities.
-- Only needs modification when default lexer is not satisfactory.
-- Generally modified along with Primitive templates.
	token COMMENT	: endOfLine(start = "//");

	lexer = "
%options testLiterals = false;

NL
	:	(	'\\r' '\\n'
		|	'\\n' '\\r'	//Improbable
		|	'\\r'
		|	'\\n'
		)
	{newline();}
	;

WS
	:	(	' '
		|	'\\t'
		)
	;

%protected
DIGIT
	:	'0'..'9'
	;

%protected
ALPHA
	:	'a'..'z'
	|	'A'..'Z'
	|	'_'
	//For Unicode compatibility (from 0000 to 00ff)
	|	'\\u00C0' .. '\\u00D6'
	|	'\\u00D8' .. '\\u00F6'
	|	'\\u00F8' .. '\\u00FF'
	;

%protected
SNAME
%v2	options {
%v2		testLiterals = true;
%v2	}
	:	(ALPHA) (ALPHA | '-' | DIGIT)*
;

NAME
	:	(
%v3			SNAME
%v2			s:SNAME {if(s.getType() != SNAME) $setType(s.getType());}
		|	'\"'!
			(	ESC
			|	'\\n' {newline();}
			|	~('\\\\'|'\\\"'|'\\n')
			)*
			'\"'!
%v3			{setText(ei.unescapeString(getText(), 1));}
		)
	;

%v3	FLOAT	:	DIGIT+ ('.' DIGIT*)?	;

%protected
ESC
	:	'\\\\'!
		(	'n' %v2{%setText(\"\\n\");}
		|	'r' %v2{%setText(\"\\r\");}
		|	't' %v2{%setText(\"\\t\");}
		|	'b' %v2{%setText(\"\\b\");}
		|	'f' %v2{%setText(\"\\f\");}
		|	'\"' %v2{%setText(\"\\\"\");}
		|	'\\'' %v2{%setText(\"\\'\");}
		|	'\\\\' %v2{%setText(\"\\\\\");}
		|	(
				('0'..'3')
				(
%v2					options {
%v2						warnWhenFollowAmbig = false;
%v2					}
				:	('0'..'7')
					(
%v2						options {
%v2							warnWhenFollowAmbig = false;
%v2						}
					:	'0'..'7'
					)?
				)?
			|	('4'..'7')
				(
%v2					options {
%v2						warnWhenFollowAmbig = false;
%v2					}
				:	('0'..'7')
				)?
			)
				{
%v2					String s = %getText;
%v2					int i;
%v2					int ret = 0;
%v2					String ans;
%v2					for (i=0; i<s.length(); ++i)
%v2						ret = ret*8 + s.charAt(i) - '0';
%v2					ans = String.valueOf((char) ret);
%v2					%setText(ans);
				}
		)
	;

STRING
	:	'\\''!
		(	ESC
		|	'\\n' {newline();}
		|	~('\\\\'|'\\''|'\\n')
		)*
		'\\''!
%v3			{setText(ei.unescapeString(getText(), 1));}
	;

	";
-- END Lexer

}