Skip to main content
aboutsummaryrefslogtreecommitdiffstats
blob: 8bc1e3b0de6f490a066ff963b076dc05eba3de22 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
-- @authors		Frédéric Jouault
-- @date		2007/07/26
-- @description	This ACG code generator generates .asm files that run on the ATL VM from ATL models.
acg ATL startsWith Unit {

-- @begin Type Encoding
	function OclType::encode() = '<DUMMY>';
	function IntegerType::encode() = 'I';
	function OclAnyType::encode() = 'J';
	function RealType::encode() = 'D';
	function BooleanType::encode() = 'B';
	function StringType::encode() = 'S';
	function Module::encode() = 'A';
	function OclModelElement::encode() = 'M' + self.model.name + '!' + self.name + ';';
	function SequenceType::encode() = 'Q' + self.elementType.encode();
	function BagType::encode() = 'G' + self.elementType.encode();
	function CollectionType::encode() = 'C' + self.elementType.encode();
	function SetType::encode() = 'E' + self.elementType.encode();
	function OrderedSetType::encode() = 'O' + self.elementType.encode();
	function TupleType::encode() = 'T' + self.attributes->collect(e | e.type.encode() + e.name + ';').prepend('').sum() + ';';
-- @end Type Encoding

	asm Module name self.name {
		field 'links' : 'NTransientLinkSet;'
		field 'col' : 'J'
		if(self.isRefining) {
			field 'enumLiteralType' : 'J'
		}

--		if(self.isRefining) {
--			report error 'refining mode not supported by ATL 2006 yet'
--		}

		operation
				context 'A'
				name 'main' {
			getasm
			push 'OclParametrizedType'
			push '#native'
			new
			dup
			push 'Collection'
			pcall 'J.setName(S):V'
			dup
			push 'OclSimpleType'
			push '#native'
			new
			dup
			push 'OclAny'
			pcall 'J.setName(S):V'
			pcall 'J.setElementType(J):V'
			set 'col'

			if(self.isRefining) {
				getasm
				push 'EnumLiteral'
				push '#native'
				new
				call 'J.oclType():J'
				set 'enumLiteralType'

				-- OclType.registerWeavingHelper(name : String, persistTo : String)
				push 'Element'
				push 'RefiningTrace'
				findme
				push 'sourceElement'
				push 'persistedSourceElement'
				pcall 'J.registerWeavingHelper(SS):V'
			}

			analyze self.elements->select(e | e isa Helper) mode register

			getasm
			push 'TransientLinkSet'
			push '#native'
			new
			set 'links'

			let ep = self.elements->select(e | e isa CalledRule)->select(e | e.isEntrypoint).first() {
				if(not ep.oclIsUndefined()) {
					getasm
					pcall 'A.' + ep.name + '():V'
				}
			}

			getasm
			pcall 'A.__matcher__():V'
			getasm
			pcall 'A.__exec__():V'

			if(self.isRefining) {
				getasm
				pcall 'A.__applyRefiningTrace__():V'
			}

			let ep = self.elements->select(e | e isa CalledRule)->select(e | e.isEndpoint).first() {
				if(not ep.oclIsUndefined()) {
					getasm
					pcall 'A.' + ep.name + '():V'
				}
			}
		}
		operation
				context 'A'
				name '__resolve__' {
			param 'value' : 'J'

			load 'value'
			getasm
			get 'col'
			call 'J.oclIsKindOf(J):B'
			if thn
					-- not a collection
				getasm
				get 'links'
				load 'value'
				call 'NTransientLinkSet;.getLinkBySourceElement(S):QNTransientLink;'
				dup
				call 'J.oclIsUndefined():B'
				if thn2
					load 'value'
					call 'NTransientLink;.getTargetFromSource(J):J'
					goto eoi2
			    thn2:
					pop
					load 'value'	-- TODO: refining_copy
			    eoi2:
				goto eoi
		    thn:
				push 'Sequence'
				push '#native'
				new
				load 'value'
				iterate
					variable self named 'e' {
						getasm
						load self
						call 'A.__resolve__(J):J'
						call 'QJ.including(J):QJ'
					}
				enditerate
				call 'QJ.flatten():QJ'
		    eoi:
		}
		operation
				context 'A'
				name 'resolveTemp' {
			param 'value' : 'J'
			param 'name' : 'S'

			getasm
			get 'links'
			load 'value'
			call 'NTransientLinkSet;.getLinkBySourceElement(S):QNTransientLink;'
			load 'value'
			load 'name'
			call 'NTransientLink;.getNamedTargetFromSource(JS):J'
		}
		operation
				context 'J'
				name '__applyReverseBinding' {
			param 'propertyName' : 'S'
			param 'target' : 'J'

			load 'target'
			getasm
			get 'col'
			call 'J.oclIsKindOf(J):B'
			if col
				-- not col
				if(self.isRefining) {
					load 'target'					-- tgtTraceElement
					call 'J.__asElement():J'	-- tgtTraceElement
					load 'propertyName'			-- tgtTraceElement, propertyName
					load 'self'					-- tgtTraceElement, propertyName, traceElement
						-- tgtTraceElement, propertyName, traceElement 
					call 'MRefiningTrace!Element;.setProperty(SJ):V'
				} else {
					getasm						-- thisModule
					load 'target'				-- thisModule, target
					call 'A.__resolve__(J):J'	-- resolvedTarget
					load 'propertyName'			-- resolvedTarget, propertyName
					load 'self'					-- resolvedTarget, propertyName, self
					pcall 'J.refSetValue(SJ):J'
				}
				goto end
		  col:
				load 'target'
				iterate
					load 'self'
					swap
					load 'propertyName'
					swap
					pcall 'J.__applyReverseBinding(SJ):V'
				enditerate
		  end:
		}
		operation
				context 'A'
				name '__matcher__' {
			foreach(r in self.elements->select(e | (e isa MatchedRule) and (not (e isa LazyMatchedRule)))->select(e | e.superRule.oclIsUndefined())) {
				getasm
				pcall 'A.__match' + r.name + '():V'
			}
		}
		operation
				context 'A'
				name '__exec__' {
			foreach(r in self.elements->select(e | e isa MatchedRule and not (e isa LazyMatchedRule))) {
				getasm
				get 'links'
				push r.name
				call 'NTransientLinkSet;.getLinksByRule(S):QNTransientLink;'
				iterate
					variable self named 'e' {
						getasm
						load self
						pcall 'A.__apply' + r.name + '(NTransientLink;):V'
					}
				enditerate
			}
		}
		if(self.isRefining) {
			operation
					context 'MRefiningTrace!Element;'
					name 'setProperty' {
				param 'propertyName' : 'S'
				param 'value' : 'J'
				param 'isAssignment' : 'B'
	
				load 'self'
				push 'Slot'
				push 'RefiningTrace'
				new
				dup
				load 'isAssignment'
				set 'isAssignment'
				dup
				load 'propertyName'
				set 'name'		-- traceElement, slot
				dup				-- traceElement, slot, slot
				load 'value'	-- traceElement, slot, slot, value
				dup
				getasm
				get 'col'
				call 'J.oclIsKindOf(J):B'
				if setPropertyThn
					-- not a collection
					call 'J.__toValue():J'
					goto setPropertyEoi
			  setPropertyThn:
			  		getasm
			  		swap
			  		call 'A.__collectionToValue(QJ):J'
			  setPropertyEoi:				-- element, slot, slot, value
				set 'value'
				set 'slots'
			}
			operation
					context 'A'
					name '__applyRefiningTrace__' {
				push 'Element'
				push 'RefiningTrace'
				findme
				push 'refiningTrace'
				call 'MMOF!Classifier;.allInstancesFrom(S):QJ'
				dup
				iterate
													-- traceElement
						dup							-- traceElement, traceElement
						get 'sourceElement'			-- traceElement, element|OclUndefined
						call 'J.oclIsUndefined():B'	-- traceElement, oclIsUndefined?
						call 'B.not():B'			-- traceElement, oclIsDefined?
						if sourceElement
							-- create the new element
													-- traceElement
							dup		 				-- traceElement, traceElement
							get 'type'				-- traceElement, typeName
							swap					-- typeName, traceElement
							dup_x1					-- traceElement, typeName, traceElement
							get 'metamodel'			-- traceElement, typeName, metamodelName
							new						-- traceElement, element
							set 'sourceElement'		-- nothing
							goto next
--TODO:use id?		
					  sourceElement:
					  								-- traceElement
							pop
					  next:
				enditerate
				dup							-- We dup refining trace to loop again and execute deletion
				iterate
											-- traceElement
						dup					-- traceElement, traceElement
						get 'sourceElement'	-- traceElement, element
						swap				-- element, traceElement
						get 'slots'
						iterate
											-- element, slot
							dup
							get 'isAssignment'	-- sourceElement, slot, isAssignment
							call 'B.not():B'
							if noAssign
												-- sourceElement, slot
								dup_x1			-- slot, sourceElement, slot
								get 'name'		-- slot, sourceElement, name
								call 'J.refUnsetValue(S):J'	-- slot, sourceElement
								swap			-- sourceElement, slot
						  noAssign:
											-- sourceElement, slot
							dup
							get 'name'		-- sourceElement, slot, name
							swap			-- sourceElement, name, slot
							get 'value'		-- sourceElement, name, value
							call 'J.__fromValue():J'	-- sourceElement, name, actualValue
							call 'J.refSetValue(SJ):J'
						enditerate
						pop
				enditerate
				iterate						-- Iteration to delete everything. We do another loop to be sure to do the deletion
											-- after all the other modifications to prevent errors
											-- traceElement
					dup						-- traceElement, traceElement
					get 'toDelete'			-- traceElement, boolean
					call 'B.not():B'		-- traceElement, boolean
					if noDelete
						dup					-- traceElement, traceElement
						get 'sourceElement'	-- traceElement, element
						delete				-- traceElement
						push 'Sequence'		
						push '#native'
						new
						call 'QJ.first():J' -- traceElement, OclUndefined
						set 'sourceElement' -- Unset sourceElement reference to avoid problems when serializing the refining trace
						goto endDeleteLoop
					noDelete:
											-- traceElement
						pop
					endDeleteLoop:
				enditerate
			}
			operation
					context 'A'
					name '__collectionToValue' {
				param 'c' : 'CJ'

				push 'CollectionVal'
				push 'RefiningTrace'
				new
				load 'c'
				iterate
											-- collectionVal, element
					call 'J.__toValue():J'	-- collectionVal, value
					swap					-- value, collectionVal
					dup_x1					-- collectionVal, value, collectionVal
					swap					-- collectionVal, collectionVal, value
					set 'elements'			-- collectionVal
				enditerate
			}
			operation
					context 'B'
					name '__toValue' {
				push 'BooleanVal'
				push 'RefiningTrace'
				new
				dup
				load 'self'
				set 'value'
			}
			operation
					context 'I'
					name '__toValue' {
				push 'IntegerVal'
				push 'RefiningTrace'
				new
				dup
				load 'self'
				set 'value'
			}
			operation
					context 'D'
					name '__toValue' {
				push 'RealVal'
				push 'RefiningTrace'
				new
				dup
				load 'self'
				set 'value'
			}
			operation
					context 'S'
					name '__toValue' {
				push 'StringVal'
				push 'RefiningTrace'
				new
				dup
				load 'self'
				set 'value'
			}
			operation
					context 'MRefiningTrace!Element;'
					name '__toValue' {
				push 'ElementVal'
				push 'RefiningTrace'
				new
				dup
				load 'self'
				set 'value'
			}
			operation
					context 'J'
					name '__toValue' {
				load 'self'
				call 'J.oclType():J'
				getasm
				get 'enumLiteralType'
				call 'J.=(J):B'
				if thn3
					-- not enum literal
					load 'self'
					call 'J.oclIsUndefined():B'
				if oclUndefined
					-- This point should only be reached for model elements
					
					push 'ElementVal'
					push 'RefiningTrace'
					new
					dup
					load 'self'
					call 'J.__asElement():J'
					set 'value'
					goto eoi3
			  oclUndefined:
					push 'NullVal'
					push 'RefiningTrace'
					new
					goto eoi3
			  thn3:
					push 'EnumLiteralVal'
					push 'RefiningTrace'
					new
					dup
					load 'self'
					call 'J.toString():S'
					set 'value'
			  eoi3:
			}
			-- should only be called on model elements
			operation
					context 'J'
					name '__asElement' {
				-- TODO: use a Map as cache
				push 'Element'
				push 'RefiningTrace'
				new
				dup
				load 'self'
				set 'sourceElement'
			}
			-- may notably be called from __applyReverseBinding if target has already been resolved (e.g., using resolveTemp)
			operation
					context 'MRefiningTrace!Element;'
					name '__asElement' {
				load 'self'
			}
			operation
					context 'MRefiningTrace!CollectionVal;'
					name '__fromValue' {
				push 'Sequence'
				push '#native'
				new
				load 'self'
				get 'elements'
				iterate
					call 'J.__fromValue():J'
					call 'QJ.append(J):QJ'
				enditerate
			}
			operation
					context 'MRefiningTrace!BooleanVal;'
					name '__fromValue' {
				load 'self'
				get 'value'
			}
			operation
					context 'MRefiningTrace!IntegerVal;'
					name '__fromValue' {
				load 'self'
				get 'value'
			}
			operation
					context 'MRefiningTrace!RealVal;'
					name '__fromValue' {
				load 'self'
				get 'value'
			}
			operation
					context 'MRefiningTrace!StringVal;'
					name '__fromValue' {
				load 'self'
				get 'value'
			}
			operation
					context 'MRefiningTrace!NullVal;'
					name '__fromValue' {
				push 'Sequence'
				push '#native'
				new
				call 'QJ.first():J'
			}
			operation
					context 'MRefiningTrace!ElementVal;'
					name '__fromValue' {
				load 'self'
				get 'value'
				get 'sourceElement'
			}
			operation
					context 'MRefiningTrace!EnumLiteralVal;'
					name '__fromValue' {
				push 'EnumLiteral'
				push '#native'
				new
				dup
				load 'self'
				get 'value'
				set 'name'
			}
		}
		analyze self.elements
	}

	asm Query name self.name {
		operation
				context 'A'
				name 'main' {
			analyze self.helpers mode register
			analyze self.body
		}
		analyze self.helpers
	}

	asm Library name self.name {
		-- we have a main operation to register the attribute helpers
		operation
				context 'A'
				name 'main' {
			analyze self.helpers mode register
		}
		analyze self.helpers
	}

-- @begin Helpers
	Helper {
		analyze self.definition.feature	
	}

	Helper mode register {
		analyze self.definition.feature	mode register
	}

	Operation mode register {
		-- nothing to do: only attributes need registration
	}

	Operation {
		operation
				context
					if self.definition.context_.oclIsUndefined() then
						'A'
					else
						self.definition.context_.context_.encode()
					endif
				name self.name {
			foreach(p in self.parameters) {
				param p.varName : 'J'
			}
			analyze self.body
		}
	}

	-- module attribute
	Attribute mode register | self.definition.context_.oclIsUndefined() {
		getasm
		analyze self.initExpression
		set self.name
	}

	Attribute | self.definition.context_.oclIsUndefined() {
		field self.name : 'J'
	}

	Attribute mode register {
		analyze self.definition.context_.context_
		push self.name
		push '__init' + self.name
		pcall 'J.registerHelperAttribute(SS):V'
	}

	Attribute {
		operation
				context self.definition.context_.context_.encode()
				name '__init' + self.name {
			analyze self.initExpression
		}
	}
-- @end Helpers

-- @begin Declarative Part
-- @begin Standard Rules
	function Rule::ruleOutPatternElements() =
		if self.outPattern.oclIsUndefined() then
			Sequence {}
		else
			self.outPattern.elements
		endif;

	MatchedRule {
		analyze self mode matcher
		analyze self mode apply
	}

	MatchedRule mode matcher | not self.superRule.oclIsUndefined() {
		-- do nothing because subRules are matched by their superRules
	}

	MatchedRule mode matcher | self.superRule.oclIsUndefined() {
		operation
				context 'A'
				name '__match' + self.name {
			foreach(ipe in self.inPattern.elements) {	-- equivalent to self.inPatternElements because self.isRoot()
				let sourceModels =
						if ipe.models.isEmpty() then
							self.module.inModels->select(e |
								-- TODO: compare models instead of names?
								e.metamodel.name = ipe.type.model.name
							)
						else
							ipe.models
						endif {
					if(sourceModels.isEmpty()) {
						report error ipe.type.model.name + ' is not a source model'
					}
					foreach(m in sourceModels) {
						push ipe.type.name	-- TODO: optimize this out of loop?
						push ipe.type.model.name
						findme
						push m.name
						call 'MMOF!Classifier;.allInstancesFrom(S):QJ'
						if(m <> sourceModels.first()) {
							call 'CJ.union(CJ):CJ'
						}
					}
				}
				iterate
					variable ipe named ipe.varName {
					[
						if(not self.inPattern.filter.oclIsUndefined()) {
							analyze self.inPattern.filter
							call 'B.not():B'
							if end
						}

						analyze self mode checkSubRules
					    end:
					]
					}
				enditerate
			}
		}
	}

	function MatchedRule::allSubRules() =
		if self.isAbstract then
			self.children
		else
			self.children.append(self)
		endif;

	-- makes sure the default rule is last
	function MatchedRule::subRules() =
		self.allSubRules()->select(e | not e.inPattern.filter.oclIsUndefined()).union(
			self.allSubRules()->select(e | e.inPattern.filter.oclIsUndefined())
		);

	function MatchedRule::rootRule() =
		if self.superRule.oclIsUndefined() then
			self
		else
			self.superRule.rootRule()
		endif;

	function MatchedRule::mostAbstractOutPatternElements() =
		if self.superRule.oclIsUndefined() then
			self.ruleOutPatternElements()
		else
			let super = self.superRule.mostAbstractOutPatternElements() in
			let superNames = super->collect(e | e.varName) in
			super.union(
				self.ruleOutPatternElements()->select(e |
					not superNames.includes(e.varName)
				)
			)
		endif;

	function MatchedRule::mostConcreteOutPatternElements() =
		if self.superRule.oclIsUndefined() then
			self.ruleOutPatternElements()
		else
			let this = self.ruleOutPatternElements() in
			let thisNames = this->collect(e | e.varName) in
			this.union(
				self.superRule.mostConcreteOutPatternElements()->select(e |
					not thisNames.includes(e.varName)
				)
			)
		endif;

	function MatchedRule::mostConcreteVariables() =
		if self.superRule.oclIsUndefined() then
			self.variables
		else
			let this = self.variables in
			let thisNames = this->collect(e | e.varName) in
			this.union(
				self.superRule.mostConcreteVariables()->select(e |
					not thisNames.includes(e.varName)
				)
			)
		endif;

	function MatchedRule::inPatternElements() =
		self.rootRule().inPattern.elements;

	function SimpleInPatternElement::actualDeclaration() =
		self.inPattern.rule.inPatternElements()->select(e | e.varName = self.varName).first();

	function OutPatternElement::actualDeclaration() =
		if self.outPattern.rule isa MatchedRule then
			self.outPattern.rule.mostAbstractOutPatternElements()->select(e | e.varName = self.varName).first()
		else
			self
		endif;

	-- subRules should be ordered with the only one without guard last (including self if not abstract)
	-- their should be only one with no guard (including self)
	-- only one should match (except the one without guard, which is "default")
	-- a subrule inpattern must have the same number of elements with the same names
	MatchedRule mode checkSubRules | self.children.size() > 0 {
		foreach(subRule in self.subRules()) {
			foreach(ipe in subRule.inPattern.elements) {
				load ipe.actualDeclaration()
				push ipe.type.name
				push ipe.type.model.name
				findme
				call 'J.oclIsKindOf(J):B'
				call 'B.not():B'
				if unmatched
			}
			if(not subRule.inPattern.filter.oclIsUndefined()) {
				analyze subRule.inPattern.filter
				call 'B.not():B'
				if unmatched
			}

			-- we only select the first subRule that matches (there should be only one anyway)
			if(subRule = self) {
				analyze self mode create
			} else {
				analyze subRule mode checkSubRules
			}
			goto end
		    unmatched(subRule):
		}
	    end:
	}

	MatchedRule mode checkSubRules {
		analyze self mode create
	}

	MatchedRule mode create {
		getasm
		get 'links'

		push 'TransientLink'
		push '#native'
		new

		dup
		push self.name
		pcall 'NTransientLink;.setRule(MATL!Rule;):V'

		foreach(ipe in self.inPattern.elements) {
			dup
			push ipe.varName
			load ipe.actualDeclaration()
			pcall 'NTransientLink;.addSourceElement(SJ):V'
		}

		foreach(v in self.mostConcreteVariables()) {
			dup
			push v.varName
			analyze v.initExpression
			dup
			variable v named v.varName {
				pcall 'NTransientLink;.addVariable(SJ):V'
			[
				let opes = self.mostConcreteOutPatternElements() {
					if(self.module.isRefining) {
						if (not opes.first().oclIsUndefined()){
							-- there is no first element because the first element is going to be dropped
							-- so no different treatment for the first element 
							if (not self.outPattern.dropPattern.oclIsUndefined()){
								analyze opes mode match
							} else {
								analyze opes.first() mode matchFirstRefining
								analyze opes.subSequence(2, opes.size()) mode match
							}
							
						}
					} else {
						analyze opes mode match
					}
				}
			]
			}
		}

		if (not self.outPattern.dropPattern.oclIsUndefined()){
			analyze self.outPattern.dropPattern
		}

		if(self.isNoDefault) {
			pushf
		} else {
			pusht
		}
		pcall 'NTransientLinkSet;.addLink2(NTransientLink;B):V'
	}

	MatchedRule mode apply | self.isAbstract {
		-- do nothing
	}

	MatchedRule mode apply | not self.isAbstract {
		operation
				context 'A'
				name '__apply' + self.name {
			param 'link' : 'NTransientLink;'
			-- TODO: only one source element for refining mode
			foreach(ipe in self.inPatternElements()) {
				load 'link'
				push ipe.varName
				call 'NTransientLink;.getSourceElement(S):J'
				variable ipe named ipe.varName {
				[
					foreach(ope in self.mostAbstractOutPatternElements()) {
						load 'link'
						push ope.varName
						call 'NTransientLink;.getTargetElement(S):J'
						variable ope named ope.varName {
						[
							foreach(v in self.mostConcreteVariables()) {
								load 'link'
								push v.varName
								call 'NTransientLink;.getVariable(S):J'
								variable v named v.varName {
								[
									analyze self.mostConcreteOutPatternElements() mode apply
									if(not self.actionBlock.oclIsUndefined()) {
										if(self.module.isRefining) {
											report error 'do block not supported in refining mode'
										} else {
											analyze self.actionBlock
										}
									}
								]
								}
							}
						]
						}
					}
				]
				}
			}
		}
	}

	attribute OutPatternElement::isRefiningMode =
		self.outPattern.rule.module.isRefining;
 
-- @begin SimpleOutPatternElement
	code SimpleOutPatternElement mode match {
		dup
		push self.varName
		if(self.isRefiningMode) {
			push 'Element'
			push 'RefiningTrace'
			new
			dup
			push self.type.name
			set 'type'
			dup
			push self.type.model.name
			set 'metamodel'
		} else {
			push self.type.name
			push self.type.model.name
			if (not self.model.oclIsUndefined()) {
				push self.model.name
				newin
			} else {
				new
			}
		}

		pcall 'NTransientLink;.addTargetElement(SJ):V'
	}

	-- TODO: removal, change...
	code SimpleOutPatternElement mode matchFirstRefining {
		dup
		push self.varName

		push 'Element'
		push 'RefiningTrace'
		new
		dup
		push self.type.name
		set 'type'
		dup
		push self.type.model.name
		set 'metamodel'
		dup
		load self.outPattern.rule.inPatternElements().first()
		set 'sourceElement'

		pcall 'NTransientLink;.addTargetElement(SJ):V'
	}

	function SimpleOutPatternElement::superElement() =
		if self.outPattern.rule isa MatchedRule then
			let superRule = self.outPattern.rule.superRule in
			if superRule.oclIsUndefined() then
				OclUndefined
			else
				superRule.mostConcreteOutPatternElements()->select(e | e.varName = self.varName).first()
			endif
		else
			OclUndefined
		endif;

	function SimpleOutPatternElement::allReverseBindings() =
		let superElement = self.superElement() in
		if superElement.oclIsUndefined() then
			Sequence {}
		else
			superElement.allReverseBindings()
		endif.union(self.reverseBindings);

	-- We create a normal template instead of a code template because this template will be
	-- called from another code template matching the same model element. If this were
	-- a code template an error will be raised when the vm tries to remove the entrance
	-- for this code template (it is registered twice, but as it is a map is has no effect
	-- so we can not remove twice)
	SimpleOutPatternElement mode applyReverseBindings {	-- element -> element
		foreach(rb in self.allReverseBindings()) {
			if(rb isa NavigationOrAttributeCallExp) {
				dup					-- element, element
				push rb.name
				analyze rb.source	-- element, element, propertyName, value
				pcall 'J.__applyReverseBinding(SJ):V'
									-- element
			} else {
				if(rb isa OperationCallExp) {
					if(rb.operationName = 'refGetValue' and rb.arguments.size() = 1) {
						dup
						analyze rb.arguments.first()
						analyze rb.source
						pcall 'J.__applyReverseBinding(SJ):V'
					} else {
						report error 'only navigations (including refGetValue) are allowed in reversebindings' 
					}
				} else {
					report error 'only navigations (including refGetValue) are allowed in reversebindings' 
				}
			}
		}
	}

	function MatchedRule::getBindings(varName, ret) =
		if self.outPattern.oclIsUndefined() then
			Sequence {}
		else
			let ope =
				self.outPattern.elements->select(e |
					e.varName = varName
				).first() in
			let retNames = ret->collect(e | e.propertyName) in
			let newRet =
				if ope.oclIsUndefined() then
					ret
				else
					ret.union(
						ope.bindings->select(e |
							not retNames.includes(e.propertyName)
						)
					)
				endif in
			if self.superRule.oclIsUndefined() then
				newRet
			else
				self.superRule.getBindings(varName, newRet)
			endif
		endif;

	function OutPatternElement::allBindings() =
		let superRule = self.outPattern.rule.superRule in
		if superRule.oclIsUndefined() then
			self.bindings
		else
			self.outPattern.rule.getBindings(self.varName, Sequence {})
		endif;

	code SimpleOutPatternElement mode apply {
		load self.actualDeclaration()	-- element
		analyze self mode applyReverseBindings
		if(self.isRefiningMode) {
			analyze self.allBindings() mode refining
		} else {
			analyze self.allBindings()
		}
		pop
	}

	code Binding {
		dup
		if(self.isAssignment) {
			push self.propertyName
			call 'J.refUnsetValue(S):J'
		}
		getasm
		analyze self.value
		call 'A.__resolve__(J):J'
		set self.propertyName
	}

	code Binding mode refining {
		dup
		push self.propertyName
		getasm
		analyze self.value
		call 'A.__resolve__(J):J'

				-- traceElement, propertyName, value
		if(self.isAssignment) {
			pusht
		} else {
			pushf
		}
		pcall 'MRefiningTrace!Element;.setProperty(SJB):V'
	}
-- @end SimpleOutPatternElement

-- ForEachOutPatternElement does not support rule inheritance.
-- It is now deprecated anyway.
-- @begin ForEachOutPatternElement
	code ForEachOutPatternElement mode match {
		if(self.isRefiningMode) {
			report error 'distinct-foreach target pattern elements are not supported in refining mode, use lazy rules instead'
		} else {
			report warning 'distinct-foreach target pattern elements are deprecated, use lazy rules instead'
			dup
			push self.varName
	
			push 'Sequence'
			push '#native'
			new
			analyze self.collection
			iterate
				pop
				push self.type.name
				push self.type.model.name
				-- NOTE: foreach patterns syntax can't handle output model specification, so "newin" instructions are not generated here
				new
				call 'CJ.including(J):CJ'
			enditerate
			pcall 'NTransientLink;.addTargetElement(SJ):V'
		}
	}

	code ForEachOutPatternElement mode apply {
		pushi 1
		variable self.type named 'counter' {			-- self.type is not a VariableDeclaration but this shouldn't matter
			analyze self.collection
			call 'CJ.asSequence():QJ'
			variable self.collection named 'collection' {	-- self.collection is not a VariableDeclaration but this shouldn't matter
				load self
				iterate
					load self.collection	-- 'collection'
					load self.type		-- 'counter'
					call 'QJ.at(I):J'
					variable self.iterator named self.iterator.varName {
						analyze self.bindings mode forEach
					}
					pop
					load self.type		-- 'counter'
					pushi 1
					call 'I.+(I):I'
					store self.type		-- 'counter'
				enditerate
			}
		}
	}

	code Binding mode forEach {
		dup
		getasm
		analyze self.value
		dup
		getasm
		get 'col'
		call 'J.oclIsKindOf(J):B'
		call 'B.not():B'
		if thn
			load self.outPatternElement.type	-- 'counter'
			call 'QJ.at(I):J'
	    thn:
		call 'A.__resolve__(J):J'
		set self.propertyName
	}
-- @end ForEachOutPatternElement

-- @begin DropPattern
    --
    -- We have to set toDelete flag to true
    --
	code DropPattern {	
		push 'Element'
		push 'RefiningTrace'
		new
		dup
		push self.outPattern.rule.inPatternElements().first().type.name
		set 'type'
		dup
		push self.outPattern.rule.inPatternElements().first().type.model.name
		set 'metamodel'
		dup
		pusht    
		set 'toDelete'
		load self.outPattern.rule.inPatternElements().first()
		set 'sourceElement'
	}

-- @end DropPattern

-- @end Standard Rules

-- @begin Lazy Rules
	LazyMatchedRule | self.isRefining {
		report error 'refining lazy matched rules not supported in ATL 2006 yet'
	}

	LazyMatchedRule | not self.superRule.oclIsUndefined() {
		-- do nothing because subRules are matched by their superRules
	}

	LazyMatchedRule | self.superRule.oclIsUndefined() {
		if(self.module.isRefining) {
			report error 'lazy rules not supported in refining mode yet'
		} else {
			operation
					context 'A'
					name self.name {
				foreach(ipe in self.inPattern.elements) {
					param ipe.varName : ipe.type.encode()
				}
	
				if(self.isUnique) {
					getasm
					get 'links'
					push self.name
					--TODO: finish this (also in VM code)
--					if(self.inPattern.elements.size() = 1) {
						load self.inPattern.elements.first().varName
--					} else {
--						push 'Tuple'
--						push '#native'
--						new				-- links, name, Tuple
--						foreach(e in self.inPattern.elements) {		-- TODO: change TransientLinkSet implementation accordingly
--							dup
--							load e.varName
--							set e.varName
--						}
--					}
					call 'NTransientLinkSet;.getLinkByRuleAndSourceElement(SJ):QNTransientLink;'
					dup
					call 'J.oclIsUndefined():B'
					if thn
						load self.inPattern.elements.first().varName
						call 'NTransientLink;.getTargetFromSource(J):J'
						goto eoo
				    thn:
				}
	
				getasm
				get 'links'
	
				push 'TransientLink'
				push '#native'
				new
	
				dup
				push self.name
				pcall 'NTransientLink;.setRule(MATL!Rule;):V'
	
				foreach(ipe in self.inPattern.elements) {
					dup
					push ipe.varName
					load ipe.varName
					pcall 'NTransientLink;.addSourceElement(SJ):V'
				}
	
				analyze self mode checkSubRules
			    eoo:
			}
		}
	}

	LazyMatchedRule mode checkSubRules | self.children.size() > 0 {
		foreach(subRule in self.subRules()) {
			foreach(ipe in subRule.inPattern.elements) {
				load ipe.varName
				push ipe.type.name
				push ipe.type.model.name
				findme
				call 'J.oclIsKindOf(J):B'
				call 'B.not():B'
				if unmatched
			}
			if(not subRule.inPattern.filter.oclIsUndefined()) {
				analyze subRule.inPattern.filter
				call 'B.not():B'
				if unmatched
			}

			-- we only select the first subRule that matches (there should be only one anyway)
			if(subRule = self) {
				foreach(v in self.mostConcreteVariables()) {
					analyze v.initExpression
					variable v named v.varName {
					[
						analyze self mode create
					]
					}
				}
			} else {
				analyze subRule mode checkSubRules
			}
			goto end
		    unmatched(subRule):
		}
	    end:
	}

	LazyMatchedRule mode checkSubRules {
		foreach(v in self.mostConcreteVariables()) {
			analyze v.initExpression
			variable v named v.varName {
			[
				analyze self mode create
			]
			}
		}
	}

	LazyMatchedRule mode create {	-- TODO: REFINING
		foreach(ope in self.mostConcreteOutPatternElements()) {
			if(ope isa ForEachOutPatternElement) {
				-- TODO: compiler crashes
				report error 'distinct-foreach target pattern elements are deprecated and not compatible with lazy rules'
			} else {
			
				dup
				push ope.varName
	
				push ope.type.name
				push ope.type.model.name
				if (not ope.model.oclIsUndefined()) {
					push ope.model.name
					newin
				} else {
					new
				}
				dup
				variable ope.actualDeclaration() named ope.varName {
					pcall 'NTransientLink;.addTargetElement(SJ):V'
				[
					pushf
					pcall 'NTransientLinkSet;.addLink2(NTransientLink;B):V'
	
					analyze self.mostConcreteOutPatternElements() mode apply
	
					if(not self.actionBlock.oclIsUndefined()) {
						analyze self.actionBlock
					}
	
					load self.mostConcreteOutPatternElements().first().actualDeclaration()
				]
				}
			}
		}
	}
-- @end Lazy Rules
-- @end Declarative Part

-- @begin OCL
-- @begin LiteralExps
-- @begin PrimitiveExps
	code BooleanExp | self.booleanSymbol {
		pusht
	}

	code BooleanExp {
		pushf
	}

	code IntegerExp {
		pushi self.integerSymbol
	}

	code RealExp {
		pushd self.realSymbol
	}

	code StringExp {
		push self.stringSymbol
	}
-- @end PrimitiveExps

	code EnumLiteralExp {
		push 'EnumLiteral'
		push '#native'
		new
		dup
		push self.name
		set 'name'
	}

	code OclUndefinedExp {
		push 'Sequence'
		push '#native'
		new
		call 'QJ.first():J'
	}

-- @begin CollectionExps
	code BagExp {
		push 'Bag'
		push '#native'
		new
		analyze self.elements {
			call 'CJ.including(J):CJ'
		}
	}

	code SequenceExp {
		push 'Sequence'
		push '#native'
		new
		analyze self.elements {
			call 'CJ.including(J):CJ'
		}
	}

	code SetExp {
		push 'Set'
		push '#native'
		new
		analyze self.elements {
			call 'CJ.including(J):CJ'
		}
	}

	code OrderedSetExp {
		push 'OrderedSet'
		push '#native'
		new
		analyze self.elements {
			call 'CJ.including(J):CJ'
		}
	}
-- @end CollectionExps

	code TupleExp {
		push 'Tuple'
		push '#native'
		new
		analyze self.tuplePart
	}

	code TuplePart {
		dup
		analyze self.initExpression
		set self.varName
	}

	code MapExp {
		push 'Map'
		push '#native'
		new
		analyze self.elements
	}

	code MapElement {
		analyze self.key
		analyze self.value
		call 'J.including(JJ):J'
	}
-- @end LiteralExps

-- @begin Types
-- @begin SimpleTypes
	code OclAnyType {
		push 'OclAny'
		push '#native'
		findme
	}

	code IntegerType {
		push 'Integer'
		push '#native'
		findme
	}

	code BooleanType {
		push 'Boolean'
		push '#native'
		findme
	}

	code RealType {
		push 'Real'
		push '#native'
		findme
	}

	code StringType {
		push 'String'
		push '#native'
		findme
	}
-- @end Simple Types

	code OclModelElement {
		push self.name
		push self.model.name
		findme
	}

	code TupleType {
		push 'TupleType'
		push '#native'
		new
		analyze self.attributes
	}

	code TupleTypeAttribute {
		dup
		push self.name
		push 'OclAny'
		push '#native'
		findme
		pcall 'J.addAttribute(SJ):V'
	}

-- @begin Parameterized Types
	code CollectionType {
		push 'OclParametrizedType'
		push '#native'
		new
		dup
		push 'Collection'
		pcall 'J.setName(S):V'
		dup
		analyze self.elementType
		pcall 'J.setElementType(J):V'
	}

	code SequenceType {
		push 'OclParametrizedType'
		push '#native'
		new
		dup
		push 'Sequence'
		pcall 'J.setName(S):V'
		dup
		analyze self.elementType
		pcall 'J.setElementType(J):V'
	}

	code SetType {
		push 'OclParametrizedType'
		push '#native'
		new
		dup
		push 'Set'
		pcall 'J.setName(S):V'
		dup
		analyze self.elementType
		pcall 'J.setElementType(J):V'
	}

	code OrderedSetType {
		push 'OclParametrizedType'
		push '#native'
		new
		dup
		push 'OrderedSet'
		pcall 'J.setName(S):V'
		dup
		analyze self.elementType
		pcall 'J.setElementType(J):V'
	}

	code BagType {
		push 'OclParametrizedType'
		push '#native'
		new
		dup
		push 'Bag'
		pcall 'J.setName(S):V'
		dup
		analyze self.elementType
		pcall 'J.setElementType(J):V'
	}
-- @end Parameterized Types
-- @end Types

	code LetExp {
		analyze self.variable.initExpression
		variable self.variable named self.variable.varName {
			analyze self.in_
		}
	}

	code IfExp {
		analyze self.condition
		if thn
			analyze self.elseExpression
			goto eoi
	    thn:
			analyze self.thenExpression
	    eoi:
	}

-- @begin VariableExp
	code VariableExp | self.referredVariable.varName = 'thisModule' {
		getasm
	}

	code VariableExp | self.referredVariable.varName = 'self' {
		load 'self'
	}

	-- is redefined for rule inheritance
	function VariableDeclaration::actualDeclaration() = self;

	code VariableExp |
			(self.referredVariable isa Parameter) or (
				if self.referredVariable isa InPatternElement then
					self.referredVariable.inPattern.rule isa LazyMatchedRule
				else
					false
				endif
			) {
		load self.referredVariable.varName
	}

	code VariableExp {
		load self.referredVariable.actualDeclaration()
	}
-- @end VariableExp

-- @begin PropertyCallExps
	code OperationCallExp |
			if self.operationName = '-' then	-- use a if to optimize
				self.arguments.size() = 0 and self.source isa NumericExp
			else
				false
			endif {
		pushi 0
		analyze self.source
		call 'J.-(J):J'
	}

	code OperationCallExp | self.source isa SuperExp {
		load 'self'
		analyze self.arguments
		supercall self.operationSignature
	}

	attribute OperationCallExp::operationSignature =
		'J.' + self.operationName + '(' + self.arguments->collect(e | 'J').prepend('').sum() + '):J';

	code OperationCallExp {
		analyze self.source
		analyze self.arguments
		call self.operationSignature
	}

	code NavigationOrAttributeCallExp {
		analyze self.source
		get self.name
	}

	code IterateExp | self.iterators.size() = 1 {
		analyze self.result.initExpression
		variable self.result named self.result.varName {
			analyze self.source
			iterate
				variable self.iterators.first() named self.iterators.first().varName {
					analyze self.body
					store self.result
				}
			enditerate
			load self.result
		}
	}

	-- WITH SEVERAL ITERATORS
	code IterateExp {
		analyze self.result.initExpression
		variable self.result named self.result.varName {
			analyze self.source
			dup
			foreach(i in self.iterators) { 
				if(i <> self.iterators.first()) {
					dup_x1
				}
				iterate
					variable i named i.varName {
					[
						analyze self.body
						store self.result
					]
					}
				enditerate
				if(i = self.iterators.last()) {
					pop
				} else {
					swap
				}
			}
			load self.result
		}
	}

-- @begin IteratorExps
	code IteratorExp | self.name = 'exists' and self.iterators.size() = 1 {
		pushf
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'B.or(B):B'
			}
		enditerate
	}

	-- WITH TWO ITERATORS
--	code IteratorExp | self.name = 'exists' and self.iterators.size() = 2 {
--		pushf							-- ret
--		analyze self.source					-- ret, Seq
--		dup							-- ret, Seq, Seq
--		iterate
--			variable self.iterators.first() named self.iterators.first().varName {
--									-- ret, Seq
--				dup_x1					-- Seq, ret, Seq
--				iterate
--					variable self.iterators.last() named self.iterators.last().varName {
--									-- Seq, ret
--						analyze self.body	-- Seq, ret, body
--						call 'B.or(B):B'	-- Seq, ret
--					}
--				enditerate
--				swap
--			}
--		enditerate
--		pop
--	}

	-- WITH SEVERAL ITERATORS
	code IteratorExp | self.name = 'exists' {
		pushf
		analyze self.source
		dup
		foreach(i in self.iterators) { 
			if(i <> self.iterators.first()) {
				dup_x1
			}
			iterate
				variable i named i.varName {
				[
					analyze self.body
					call 'B.or(B):B'
				]
				}
			enditerate
			if(i = self.iterators.last()) {
				pop
			} else {
				swap
			}
		}
	-- ACTUAL SEMANTICS (recursive):
--		pushf
--		analyze self.source
--		f(iterators, statements) { 
--			if(iterators.size() > 1) {
--				dup
--			}
--			iterate
--				variable iterators.first() named iterators.first().varName {
--					if(iterators.size() > 1) {
--						f(iterators.subSequence(2, iterators.size() - 1), statements)
--					} else {
--						statements
--					}
--				}
--			enditerate
--		} (self.iterators, {
--					analyze self.body
--					call 'B.or(B):B'
--				}
--		)
	}

	code IteratorExp | self.name = 'forAll' and self.iterators.size() = 1 {
		pusht
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'B.and(B):B'
			}
		enditerate
	}
	
	-- WITH SEVERAL ITERATORS
	code IteratorExp | self.name = 'forAll' {
		pusht
		analyze self.source
		dup
		foreach(i in self.iterators) { 
			if(i <> self.iterators.first()) {
				dup_x1
			}
			iterate
				variable i named i.varName {
				[
					analyze self.body
					call 'B.and(B):B'
				]
				}
			enditerate
			if(i = self.iterators.last()) {
				pop
			} else {
				swap
			}
		}
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'isUnique' and self.iterators.size() = 1 {
		analyze self.source
		dup
		call 'CJ.size():I'
		swap

		push 'Set'
		push '#native'
		new
		swap
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'CJ.including(J):CJ'
			}
		enditerate

		call 'CJ.size():I'
		call 'I.=(I):I'
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'any' and self.iterators.size() = 1 {
		push 'Sequence'
		push '#native'
		new
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'B.not():B'
				if thn
					load self.iterators.first()
					call 'CJ.including(J):CJ'
			    thn:
			}
		enditerate
		call 'CJ.asSequence():QJ'
		call 'QJ.first():J'
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'one' and self.iterators.size() = 1 {
		push 'Sequence'
		push '#native'
		new
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'B.not():B'
				if thn
					load self.iterators.first()
					call 'CJ.including(J):CJ'
			    thn:
			}
		enditerate
		call 'CJ.size():I'
		pushi 1
		call 'I.=(I):I'
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'select' and self.iterators.size() = 1 {
		push 'Sequence'
		push '#native'
		new
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'B.not():B'
				if thn
					load self.iterators.first()
					call 'CJ.including(J):CJ'
			    thn:
			}
		enditerate
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'reject' and self.iterators.size() = 1 {
		push 'Sequence'
		push '#native'
		new
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				if thn
					load self.iterators.first()
					call 'CJ.including(J):CJ'
			    thn:
			}
		enditerate
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'collect' and self.iterators.size() = 1 {
		push 'Sequence'
		push '#native'
		new
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {
				analyze self.body
				call 'CJ.including(J):CJ'
			}
		enditerate
	}

	-- One iterator max (from OCL spec)
	code IteratorExp | self.name = 'sortedBy' and self.iterators.size() = 1 {
		push 'Sequence'
		push '#native'
		new
		analyze self.source
		iterate
			variable self.iterators.first() named self.iterators.first().varName {

				dup
				call 'CJ.isEmpty():B'
				if thn
					dup
					pushi 1
					swap
					iterate
						load self.iterators.first()
						swap
						store self.iterators.first()
						analyze self.body
						swap
						store self.iterators.first()
						analyze self.body

						call 'I.>(I):B'
						if thn2
							pushi 1
							call 'I.+(I):I'
					    thn2:
					enditerate

					load self.iterators.first()
					call 'QJ.insertAt(IJ):QJ'

					goto eoi
			    thn:
					load self.iterators.first()
					call 'QJ.append(J):QJ'
			    eoi:
			}
		enditerate
	}

	code IteratorExp | self.iterators.size() = 1 {
		report error 'iterator \'' + self.name + '\' not supported'
	}

	code IteratorExp {
		report error 'iterator \'' + self.name + '\' not supported with several iterators'
	}
-- @end IteratorExps
-- @end PropertyCallExps
-- @end OCL

-- @begin Imperative Part

	CalledRule {	-- TODO: REFINING
		if(self.module.isRefining) {
			report error 'called rules not supported in refining mode yet'
		} else {
			operation
					context 'A'
					name self.name {
				foreach(p in self.parameters) {
					param p.varName : 'J'
				}
				foreach(v in self.variables) {
					analyze v.initExpression
					variable v named v.varName {
					[
						foreach(ope in self.ruleOutPatternElements()) {
							push ope.type.name
							push ope.type.model.name
							if (not ope.model.oclIsUndefined()) {
								push ope.model.name
								newin
							} else {
								new
							}
							variable ope named ope.varName {
							[
								foreach(ope in self.ruleOutPatternElements()) {
									load ope
									analyze ope.bindings
									pop
								}
								if(not self.actionBlock.oclIsUndefined()) {
									analyze self.actionBlock
								}
							]
							}
						}
					]
					}
				}
			}
		}
	}

	code ActionBlock {
		analyze self.statements
	}

	code BindingStat | self.source isa NavigationOrAttributeCallExp {
		analyze self.source.source
		if(self.isAssignment) {
			push self.source.name
			call 'J.refUnsetValue(S):J'
		}
		analyze self.value
		set self.source.name
	}

	code BindingStat | self.source isa VariableExp {
		analyze self.value
		if(self.source.referredVariable isa Parameter) {
			store self.source.referredVariable.varName
		} else {
			store self.source.referredVariable
		}
	}

	code BindingStat {
		report error 'only variables or navigations are allowed on the left of a binding statement'
	}

	-- TODO:
	--	- calling OperationCallExp in a special mode would not prevent its location to be written in the line number table
	--	- compiler calls to operations having no return value should also be changed into pcall
	code ExpressionStat | self.expression isa OperationCallExp {
		analyze self.expression.source
		analyze self.expression.arguments
		pcall self.expression.operationSignature
	}

	code ExpressionStat {
		analyze self.expression
	}

	code IfStat {
		analyze self.condition
		if thn
			analyze self.elseStatements
			goto eoi
	    thn:
			analyze self.thenStatements
	    eoi:
	}

	code ForStat {
		analyze self.collection
		iterate
			variable self.iterator named self.iterator.varName {
				analyze self.statements
			}
		enditerate
	}
-- @end Imperative Part
}

Back to the top