Skip to main content
aboutsummaryrefslogtreecommitdiffstats
blob: f111a913d6fcc7a5219cba9ad8633c5117b1f320 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
/*******************************************************************************
 * Copyright (c) 2011 protos software gmbh (http://www.protos.de).
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v1.0
 * which accompanies this distribution, and is available at
 * http://www.eclipse.org/legal/epl-v10.html
 * 
 * CONTRIBUTORS:
 * 		Henrik Rentz-Reichert (initial contribution)
 * 
 *******************************************************************************/

package org.eclipse.etrice.generator.java.gen

import org.eclipse.xtext.generator.IFileSystemAccess
import org.eclipse.xtext.generator.JavaIoFileSystemAccess
import com.google.inject.Inject

import static extension org.eclipse.xtext.xtend2.lib.ResourceExtensions.*
import static extension org.eclipse.xtext.xtend2.lib.*

import org.eclipse.etrice.core.room.*
import org.eclipse.etrice.generator.etricegen.*
import org.eclipse.etrice.generator.java.setup.Logger

class ActorClassGen {
	
	@Inject extension JavaIoFileSystemAccess fileAccess
	@Inject extension StdExtensions stdExt
	@Inject extension ProcedureHelpers helpers
	@Inject extension StateMachineGen stateMachineGen
	@Inject Logger logger
	
	def doGenerate(Root root) {
		for (xpac: root.xpActorClasses) {
			var path = xpac.actorClass.generationTargetPath+xpac.actorClass.getPath
			var file = xpac.actorClass.getFileName
			logger.logInfo("generating ActorClass implementation '"+file+"' in '"+path+"'")
			fileAccess.setOutputPath(path)
			fileAccess.generateFile(file, root.generate(xpac, xpac.actorClass))
		}
	}
	
	def generate(Root root, ExpandedActorClass xpac, ActorClass ac) {'''
		package «ac.getPackage»;
		
		import org.eclipse.etrice.runtime.java.messaging.Address;
		import org.eclipse.etrice.runtime.java.messaging.IRTObject;
		import org.eclipse.etrice.runtime.java.messaging.IMessageReceiver;
		import org.eclipse.etrice.runtime.java.modelbase.ActorClassBase;
		import org.eclipse.etrice.runtime.java.modelbase.SubSystemClassBase;
		import org.eclipse.etrice.runtime.java.modelbase.InterfaceItemBase;
		import org.eclipse.etrice.runtime.java.debugging.DebuggingService;
		
		«FOR model : root.getReferencedModels(ac)»import «model.name».*;
		«ENDFOR»
		
		«FOR pc : root.getReferencedProtocols(ac)»import «pc.^package».«pc.name».*;
		«ENDFOR»
		
		«helpers.UserCode(ac.userCode1)»
		
		
		public «IF ac.abstract»abstract «ENDIF»class «ac.name» extends «IF ac.base!=null»«ac.base.name»«ELSE»ActorClassBase«ENDIF» {
		
			«helpers.UserCode(ac.userCode2)»
			
			//--------------------- ports
			«FOR ep : ac.getEndPorts()»
				protected «ep.getPortClassName()» «ep.name» = null;
			«ENDFOR»
			//--------------------- saps
			«FOR sap : ac.strSAPs»
				protected «sap.getPortClassName()» «sap.name» = null;
			«ENDFOR»
			//--------------------- services
			«FOR svc : ac.serviceImplementations»
				protected «svc.getPortClassName()» «svc.spp.name» = null;
			«ENDFOR»
		
			//--------------------- interface item IDs
			«FOR ep : ac.getEndPorts()»
				protected static final int IFITEM_«ep.name» = «xpac.getInterfaceItemLocalId(ep)+1»;
			«ENDFOR»
			«FOR sap : ac.strSAPs»
				protected static final int IFITEM_«sap.name» = «xpac.getInterfaceItemLocalId(sap)+1»;
			«ENDFOR»
			«FOR svc : ac.serviceImplementations»
				protected static final int IFITEM_«svc.spp.name» = «xpac.getInterfaceItemLocalId(svc.spp)+1»;
			«ENDFOR»
			
			«helpers.Attributes(ac.attributes)»
			«helpers.Operations(ac.operations)»
		
			//--------------------- construction
			public «ac.name»(IRTObject parent, String name, Address[][] port_addr, Address[][] peer_addr){
				«IF ac.base==null»
					super(parent, name, port_addr[0][0], peer_addr[0][0]);
				«ELSE»
					super(parent, name, port_addr, peer_addr);
				«ENDIF»
				setClassName("«ac.name»");
				
				// initialize attributes
				«FOR a : ac.attributes »
					«IF a.defaultValueLiteral!=null»
						«a.name» = «a.defaultValueLiteral»;
					«ELSEIF a.type.type!=null»
						«a.name» = new «a.type.type.name»();
					«ENDIF»
				«ENDFOR»
		
				// own ports
				«FOR ep : ac.getEndPorts()»
					«ep.name» = new «ep.getPortClassName()»(this, "«ep.name»", IFITEM_«ep.name», «IF ep.multiplicity==1»0, «ENDIF»port_addr[IFITEM_«ep.name»]«IF ep.multiplicity==1»[0]«ENDIF», peer_addr[IFITEM_«ep.name»]«IF ep.multiplicity==1»[0]«ENDIF»); 
				«ENDFOR»
				// own saps
				«FOR sap : ac.strSAPs»
					«sap.name» = new «sap.getPortClassName()»(this, "«sap.name»", IFITEM_«sap.name», 0, port_addr[IFITEM_«sap.name»][0], peer_addr[IFITEM_«sap.name»][0]); 
				«ENDFOR»
				// own service implementations
				«FOR svc : ac.serviceImplementations»
					«svc.spp.name» = new «svc.getPortClassName()»(this, "«svc.spp.name»", IFITEM_«svc.spp.name», port_addr[IFITEM_«svc.spp.name»], peer_addr[IFITEM_«svc.spp.name»]); 
				«ENDFOR»
			}
			
		
			//--------------------- lifecycle functions
			public void init(){
				initUser();
			}
		
			public void start(){
				startUser();
			}
		
			«IF !ac.overridesStop()»
			public void stop(){
				stopUser();
			}
			«ENDIF»
			
			public void destroy(){
				destroyUser();
			}	
		
			«IF ac.stateMachine != null»
				«stateMachineGen.genStateMachine(xpac, ac)»
			«ELSEIF !xpac.hasStateMachine()»
				//--------------------- no state machine
				@Override
				public void receiveEvent(InterfaceItemBase ifitem, int evt, Object data) {
				handleSystemEvent(ifitem, evt, data);
				}
				
				@Override
				public void executeInitTransition(){
				}
			«ENDIF»
		};
	'''
	}
	
	def msgArgs(Message msg) {
		'''«IF msg.data!=null»«msg.data.defaultValue()»«ENDIF»'''
	}
}

Back to the top