blob: d08d44d17fc4cc2fbfaad414cc4bd6ea52b3a003 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
|
/*******************************************************************************
* Copyright (c) 2012 protos software gmbh (http://www.protos.de).
* All rights reserved. This program and the accompanying materials
* are made available under the terms of the Eclipse Public License v1.0
* which accompanies this distribution, and is available at
* http://www.eclipse.org/legal/epl-v10.html
*
* CONTRIBUTORS:
* Juergen Haug and Thomas Schuetz (initial contribution)
*
*******************************************************************************/
grammar org.eclipse.etrice.core.Config with org.eclipse.xtext.common.Terminals
generate config "http://www.eclipse.org/etrice/core/Config"
import "http://www.eclipse.org/emf/2002/Ecore" as ecore
import "platform:/resource/org.eclipse.etrice.core.room/src-gen/org/eclipse/etrice/core/Room.ecore" as room
ConfigModel:
imports+=Import*
configElements+=ConfigElement*;
ConfigElement:
SubSystemConfig | ActorClassConfig | ActorInstanceConfig | ProtocolClassConfig;
SubSystemConfig:
'SubSystemConfig' subSystem=[room::SubSystemClass] '{'
dynConfig=DynamicConfig
'}';
DynamicConfig:
'dynamic configuration' '{'
((('file path' filePath=STRING) |
(('user import' userCode1=STRING)
('user constructor' userCode2=STRING))) &
('polling timer [ms]' polling=INT)?)
'}';
/*
* Validation:
* duplicates config, attributes
*/
ActorClassConfig:
'ActorClassConfig' actor=[room::ActorClass|FQN] '{'
attributes+=AttrClassConfig*
'}';
/*
* Validation:
* duplicates config, attributes
* valid instance reference
* Proposal:
* attributes
*/
ActorInstanceConfig:
'ActorInstanceConfig' root=[room::SubSystemClass|FQN] '/' path=RefPath '{'
attributes+=AttrInstanceConfig* &
ports+=PortInstanceConfig*
'}';
ProtocolClassConfig:
'ProtocolClassConfig' protocol=[room::ProtocolClass|FQN] '{'
(('regular' regular=PortClassConfig)? &
('conjugate' conjugated=PortClassConfig)?)
'}';
PortClassConfig:
{PortClassConfig} 'Port' '{'
attributes+=AttrClassConfig*
'}';
PortInstanceConfig:
'InterfaceItem' item=[room::InterfaceItem|ID] '{'
attributes+=AttrInstanceConfig*
'}';
/*
* Validation:
* correct value type
* Proposal:
* correct Literal
*/
AttrConfig:
AttrClassConfig | AttrInstanceConfig;
/*
* Validation:
* correct min, max type + available
* min <= value <= max
* if !value -> min <= attribute.defaultValue <= max
* character length
*
*/
AttrClassConfig:
'Attr' attribute=[room::Attribute] ('=' value=LiteralArray)? ('{'
(('min' '=' min=NumberLiteral)? &
('max' '=' max=NumberLiteral)?)
attributes+=AttrClassConfig*
'}')?;
AttrInstanceConfig:
'Attr' attribute=[room::Attribute] ('=' value=LiteralArray)? ('{'
(dynConfig?='dynamic configuration' (readOnly?='read' | 'write'))?
attributes+=AttrInstanceConfig*
'}')?;
/*
* Proposal:
* for ActorInstanceConfig
*/
RefPath:
refs+=ID ('/' refs+=ID)*;
// -------------------- from org.eclipse.etrice.core.Room.xtext ---------------
Import:
'import' (importedNamespace=ImportedFQN 'from' | 'model') importURI=STRING;
ImportedFQN:
FQN ('.*')?;
FQN:
ID ('.' ID)*;
// -----------------------------------------------------------------------------
//enum Unit:
// N|
// W|
// S = 's'|
// KG = 'kg'|
// M = 'm'|
// C|
// NM|
// RPM|
// V|
// A|
// HZ = 'Hz'|
// KW
//;
// LiteralArray = BooleanLiteral+|NumberLiteral+
// LiteralArray = StringLiteral
LiteralArray:
literals+=Literal (',' literals+=Literal)*;
// Value Types for Attributes
Literal:
BooleanLiteral |
NumberLiteral |
StringLiteral;
BooleanLiteral:
{BooleanLiteral} ('false' | isTrue?='true');
NumberLiteral:
IntLiteral | RealLiteral;
RealLiteral:
{RealLiteral} value=Real;
IntLiteral:
{IntLiteral} value=Integer;
StringLiteral:
{StringLiteral} value=STRING;
Integer returns ecore::ELong:
SignedInteger | Hexadecimal;
SignedInteger hidden():
('+' | '-')? INT;
Hexadecimal hidden():
HEX;
Real returns ecore::EDouble:
Decimal | DotDecimal | DecimalDot | DecimalExp;
Decimal hidden():
('+' | '-')? INT '.' INT;
DotDecimal hidden():
('+' | '-')? '.' INT;
DecimalDot hidden():
('+' | '-')? INT '.';
DecimalExp hidden():
('+' | '-')? INT '.' INT EXP;
terminal EXP:
('e'|'E') ('+' | '-')? ('0'..'9')+;
terminal HEX:
('0x' | '0X') ('0'..'9' | 'a'..'f' | 'A'..'F')+;
|
